Cum se construieşte un avatar 2: Pose Stand RO

Catégories / Category Forums

Infographie

téléchargement / download

All Languages

Publicité SL

Social

Cum se construieşte un avatar 2: Pose Stand RO

Tutorial Building România

Written by Rienne Verne

Pentru a construi sau modifica propriul avatar, aveţi nevoie de o unealtă specială, numită Pose Stand.
Acest Pose Stand vă permite să plasaţi în poziţie corectă primii pe avatarul dumneavoastră.
Puteţi foarte uşor să vă construiţi propriul Pose Stand.

Pentru a construi Pose Stand-ul, aveţi nevoie de un script şi o animaţie, puse în interiorul unui prim.

1°) Creaţi un cilindru.

2°) Intraţi în modul de editare (CTRL + 3) şi daţi clic pe tab-ul "OBJET".

3°) Modificaţi dimensiunile cilindrului:

X = 1.000

Y = 1.000

Z = 0.100

4°) Apoi modificaţi valorile pentru Taper:

X = 0.30 şi Y = 0.30

5°) Puneţi o animaţie din inventar în interiorul cilindrului (găsiţi multe animaţii gratuite în Second Life).

6°) Puneţi scriptul pe care îl găsiţi în Library la secţiunea Scripts sau alegeţi tab-ul "Content" din fereastra Build şi apăsaţi butonul "New Script" şi editaţi noul script.

7°) Copiaţi textul de mai jos şi înlocuiţi conţinutul noului script din cilindru cu acesta.

// ================================================================

// Când un avatar este asezat pe acest prim este animat
// folosindu-se animatia din interiorul primului
//

string g_sit_text = "Pose";

// ==============================================================
// Stop toute les animations
stop_anims( key agent )
{
    list    l = llGetAnimationList( agent );
    integer    lsize = llGetListLength( l );
    integer i;
    for ( i = 0; i < lsize; i++ )
    {
        llStopAnimation( llList2Key( l, i ) );
    }
}

// ==============================================================
default
{
    on_rez ( integer param )
    {
       llResetScript();
    }

    state_entry()
    {
        llSitTarget( < 0.0, 0.0, 1.5 > , ZERO_ROTATION );
        llSetSitText( g_sit_text );
    }

    run_time_permissions(integer permissions)
    {
        if (permissions & PERMISSION_TRIGGER_ANIMATION)
        {
            key agent = llGetPermissionsKey();
            if ( llGetAgentSize( agent ) != ZERO_VECTOR )
            {

                stop_anims( agent );
                llStartAnimation( llGetInventoryName( INVENTORY_ANIMATION, 0) );
            }
        }
        else
        {
            llOwnerSay("FAILED to initialize");
            llResetScript();
        }
    }

changed(integer change)
{

        if (change & CHANGED_LINK)
        {


            key agent = llAvatarOnSitTarget();
            if (agent)
            {
                llRequestPermissions( agent, PERMISSION_TRIGGER_ANIMATION );
            }
            else
            {


                agent = llGetPermissionsKey();
                if ( llGetAgentSize( agent ) != ZERO_VECTOR )
                {

                    if ( llGetPermissions() & PERMISSION_TRIGGER_ANIMATION )
                    {
                        stop_anims( agent );
                    }
                    llResetScript();
                }
            }
        }

}

    touch_start( integer num )
    {
        llSay( 0, "Dacă doriţi, puteţi să înlocuiţi animaţia cu alta la alegere" );
        llSay( 0, "Daţi clic dreapta şi alegeţi Pose pentru a începe animaţia" );
    }
}

Dacă doriţi puteţi schimba culoarea şi textura Pose Stand-ului dumneavoastră.

Dacă doriţi să creaţi propria animaţie,

citiţi articolul: Cum se creează o animaţie pentru Second Life?

Iată Pose Stand-ul în acţiune:

Add comment

JComments