Building an Avatar 2: The Pose Stand

Catégories / Category Forums

FAQ & +

Infographie

Qui est online

Main Menu

téléchargement / download

English Tutorial

All Languages

Publicité SL

Social

Building an Avatar 2: The Pose Stand

Tutorial Build

Written by Rienne Verne

For altering your own avatar, you will always need a special tool called "Pose Stand".
This Pose Stand allows you to place the prims correctly on the avatar's body.
You can build your own Pose Stand very easily.

You will need a script and an animation, inside of an object that will serve as pose stand. For building your own pose stand, you have to follow the next steps:

1°) Create a Cylinder on the ground.

2°) Select the cylinder and enter in the Edit mode (Pressing CTRL + 3 will bring the Build window in Edit mode on your screen). Go to the "OBJECT" tab.

3°) Modify the size of the cylinder:

X = 1.000

Y = 1.000

Z = 0.100

4°) Modify the Taper values for your cylinder to:

X = 0.30 and Y = 0.30

5°) Drag-and-drop an animation inside the cylinder (You can find many free animations in Second Life, or you can make your own animations. For this pose stand, you will need an animation that brings your avatar in the Editing Appearance position).

6°) Drag-and-drop the script from your library scripts or open the "Content" tab, click of the "New Script" button and edit the default script.

7°) Copy the following script and paste it to replace the default script:

// ================================================================

// When the avatar sits on the prim, the animation inside the prim will be used
// to animate the avatar

string g_sit_text = "Pose";

// ==============================================================
// Stop all the animations
stop_anims( key agent )
{
    list    l = llGetAnimationList( agent );
    integer    lsize = llGetListLength( l );
    integer i;
    for ( i = 0; i < lsize; i++ )
    {
        llStopAnimation( llList2Key( l, i ) );
    }
}

// ==============================================================
default
{
    on_rez ( integer param )
    {
       llResetScript();
    }

    state_entry()
    {
        llSitTarget( < 0.0, 0.0, 1.5 > , ZERO_ROTATION );
        llSetSitText( g_sit_text );
    }

    run_time_permissions(integer permissions)
    {
        if (permissions & PERMISSION_TRIGGER_ANIMATION)
        {
            key agent = llGetPermissionsKey();
            if ( llGetAgentSize( agent ) != ZERO_VECTOR )
            {

                stop_anims( agent );
                llStartAnimation( llGetInventoryName( INVENTORY_ANIMATION, 0) );
            }
        }
        else
        {
            llOwnerSay("FAILED to initialize");
            llResetScript();
        }
    }

changed(integer change)
{

        if (change & CHANGED_LINK)
        {


            key agent = llAvatarOnSitTarget();
            if (agent)
            {
                llRequestPermissions( agent, PERMISSION_TRIGGER_ANIMATION );
            }
            else
            {


                agent = llGetPermissionsKey();
                if ( llGetAgentSize( agent ) != ZERO_VECTOR )
                {

                    if ( llGetPermissions() & PERMISSION_TRIGGER_ANIMATION )
                    {
                        stop_anims( agent );
                    }
                    llResetScript();
                }
            }
        }

}

    touch_start( integer num )
    {
        llSay( 0, "If you want, you can replace the pose with one of your choice");
        llSay( 0, "Right click and choose Pose to start the pose animation" );
    }
}

You can change the color of your Pose Stand.

If your want to build your own animation,

read the tutorial: How can I build an animation for Second Life?

Using a Pose Stand:

Add comment

JComments